ArduinoとシリアルLED（WS2812B）

/*
  Created by Toshihiko Arai.
  https://101010.fun/iot/arduino-serial-led.html
*/

#include <Adafruit_NeoPixel.h>

const int DIN_PIN = 1; // D1
const int LED_COUNT = 60; // LEDの数

Adafruit_NeoPixel pixels(LED_COUNT, DIN_PIN, NEO_GRB + NEO_KHZ800);

void setup() {
  pixels.begin();
}

void loop() {
  pixels.clear();
  pixels.setPixelColor(0, pixels.Color(128, 0, 0)); // 0番目の色を変える
  pixels.show();
}

void loop() {
  pixels.clear();
  pixels.setPixelColor(0, pixels.Color(128, 0, 0)); // red
  pixels.show();
  delay(1000);

  pixels.clear();
  pixels.setPixelColor(0, pixels.Color(0, 128, 0)); // green
  pixels.show();
  delay(1000);

  pixels.clear();
  pixels.setPixelColor(0, pixels.Color(0, 0, 128)); // blue
  pixels.show();
  delay(1000);
}

void loop() {
  for(int i=0; i<LED_COUNT; i++) {
    pixels.clear();
    pixels.setPixelColor(i, pixels.Color(0, 0, 128)); // red
    pixels.show();
    delay(10);
  }
}

/*
  Created by Toshihiko Arai.
  https://101010.fun/iot/arduino-serial-led.html
*/

#include <Adafruit_NeoPixel.h>

const int DIN_PIN = 1; // D1
const int LED_COUNT = 60; // LEDの数

Adafruit_NeoPixel pixels(LED_COUNT, DIN_PIN, NEO_GRB + NEO_KHZ800);

void setup() {
  pixels.begin();
}

uint32_t red = pixels.Color(128, 0, 0);
uint32_t orange = pixels.Color(128, 82, 0);
uint32_t yellow = pixels.Color(128, 128, 0);
uint32_t green = pixels.Color(0, 128, 0);
uint32_t cyan = pixels.Color(0, 128, 128);
uint32_t blue = pixels.Color(0, 0, 128);
uint32_t purple = pixels.Color(128, 0, 128);

uint32_t rainbow_color[] = {red, orange, yellow, green, cyan, blue, purple};
int rainbow_index[] = {6, 5, 4, 3, 2, 1, 0};

void loop() {
  
  for(int i = 0; i < LED_COUNT; i++) {    
    pixels.clear();    
    for(int j = 0; j < 7; j++) {
      rainbow_index[j] = i + 6 - j;
      if(rainbow_index[j] >= LED_COUNT) rainbow_index[j] -= LED_COUNT;
      
      pixels.setPixelColor(rainbow_index[j], rainbow_color[j]);
    }
    pixels.show();
    delay(20);
  }
}

/*
  Created by Toshihiko Arai.
  https://101010.fun/arduino-serial-led.html
*/

#include <Adafruit_NeoPixel.h>

const int POT_R = 3; // A3
const int POT_G = 2; // A2
const int POT_B = 1; // A1
const int DIN_PIN = 0; // D0
const int LED_COUNT = 60; // LEDの数

Adafruit_NeoPixel pixels(LED_COUNT, DIN_PIN, NEO_GRB + NEO_KHZ800);

void setup() {
  pinMode(POT_R, INPUT);
  pinMode(POT_G, INPUT);
  pinMode(POT_B, INPUT);
  pixels.begin();
  pixels.clear();
  Serial.begin(9600);
}

void loop() {

  int R = int(analogRead(POT_R) / 1023.0 * 255.0);
  int G = int(analogRead(POT_G) / 1023.0 * 255.0);
  int B = int(analogRead(POT_B) / 1023.0 * 255.0);
  Serial.printf("R:%d G:%d B:%d\n", R, G, B);
  for(int i=0; i<LED_COUNT; i++) {
    pixels.setPixelColor(i, pixels.Color(R, G, B)); // red
    pixels.show();
  }
  delay(100);
}

.
├── lib
│   ├── RotaryEncoder
│   │   ├── RotaryEncoder.cpp
│   │   └── RotaryEncoder.h
│   └── WS2812B
│       ├── Adafruit_NeoPixel.cpp
│       ├── Adafruit_NeoPixel.h
│       ├── esp.c
│       ├── esp8266.c
│       ├── kendyte_k210.c
│       └── rp2040_pio.h
├── platformio.ini
└── src
    └── main.cpp

/**
 * @file main.cpp
 * @author Toshihiko Arai
 * @brief Neopixel（WS2812B）とPro Microを使ったRGBライト
 * @version 1.0
 * @date 2023-01-02
 *
 * @copyright Copyright (c) 101010.fun 2023
 *
 */
#include <Adafruit_NeoPixel.h>
#include <Arduino.h>
#include <RotaryEncoder.h>

#define NEO_PIN 5
#define NUMPIXELS 60
Adafruit_NeoPixel pixels(NUMPIXELS, NEO_PIN, NEO_GRB + NEO_KHZ800);

/**
 * @brief  ロータリーエンコーダ
 * A相、B相
 */
#define RE_A A2
#define RE_B A1
#define ROTARY_STEPS 4       // 色相Hueのステップ数
#define ROTARY_MIN 0         // 色相Hueの最小
#define ROTARY_MAX 360       // 色相Hueの最大
#define ROTARY_START_POS 90  // 色相Hueの初期値

RotaryEncoder encoder(RE_A, RE_B, RotaryEncoder::LatchMode::TWO03);
int lastPos = ROTARY_START_POS - 2;
int rgb[3];

/**
 * @brief 参考: https://www.codespeedy.com/hsv-to-rgb-in-cpp/
 * 
 * @param H 色相(Hue)
 * @param S 彩度(Saturation)
 * @param V 明度(Value)
 * @param rgb 
 */
void HSVtoRGB(float H, float S, float V, int* rgb) {
    if (H > 360 || H < 0 || S > 100 || S < 0 || V > 100 || V < 0) {
        Serial.println("The givem HSV values are not in valid range");
        return;
    }
    float s = S / 100;
    float v = V / 100;
    float C = s * v;
    float X = C * (1 - abs(fmod(H / 60.0, 2) - 1));
    float m = v - C;
    float r, g, b;
    if (H >= 0 && H < 60) {
        r = C, g = X, b = 0;
    } else if (H >= 60 && H < 120) {
        r = X, g = C, b = 0;
    } else if (H >= 120 && H < 180) {
        r = 0, g = C, b = X;
    } else if (H >= 180 && H < 240) {
        r = 0, g = X, b = C;
    } else if (H >= 240 && H < 300) {
        r = X, g = 0, b = C;
    } else {
        r = C, g = 0, b = X;
    }
    rgb[0] = int((r + m) * 255);
    rgb[1] = int((g + m) * 255);
    rgb[2] = int((b + m) * 255);
}

void demo(float beginHue) {
    for (int i = 0; i < NUMPIXELS; i++) {
        float hue = 360.0 * (float(i) / float(NUMPIXELS)) + beginHue;
        if (hue >= 360.0) {
            hue -= 360.0;
        }

        // Serial.println(hue);
        HSVtoRGB(hue, 100.0, 100.0, rgb);

        int red = rgb[0];
        int green = rgb[1];
        int blue = rgb[2];

        pixels.setPixelColor(i, pixels.Color(red, green, blue));
    }
    pixels.show();

    if (beginHue >= 360.0) {
        Serial.println("Done demo.");
        return;
    } else {
        beginHue += 3.6;
        // Serial.println(beginHue);
        demo(beginHue);
    }
}

void setup(void) {
    Serial.begin(115200);
    pixels.begin();
    encoder.setPosition(ROTARY_START_POS / ROTARY_STEPS);
    pixels.clear();
    demo(0.0);
    demo(0.0);
    demo(0.0);
    demo(0.0);
    demo(0.0);
    demo(0.0);
}

void loop() {
    encoder.tick();  // just call tick() to check the state.

    int newPos = encoder.getPosition() * ROTARY_STEPS;

    if (newPos < ROTARY_MIN) {
        encoder.setPosition(ROTARY_MAX / ROTARY_STEPS);
        newPos = ROTARY_MAX;

    } else if (newPos > ROTARY_MAX) {
        encoder.setPosition(ROTARY_MIN / ROTARY_STEPS);
        newPos = ROTARY_MIN;
    }

    if (lastPos != newPos) {
        Serial.println(lastPos);
        Serial.println(newPos);
        
        lastPos = newPos;
        float hue = float(lastPos);
        HSVtoRGB(hue, 100.0, 100.0, rgb);

        // Serial.println(lastPos);
        // Serial.println(hue);
        //  Serial.println(rgb[0]);
        int red = rgb[0];
        int green = rgb[1];
        int blue = rgb[2];
        // Serial.println(red);
        for (int i = 0; i < NUMPIXELS; i++) {
            pixels.setPixelColor(i, pixels.Color(red, green, blue));
        }
        pixels.show();
        delay(50);
    }
}