ArduinoでC++で作った自作ライブラリを使う方法

/*
    GasSensor.h - Library for Gas sensor.
    Created by Toshihiko Arai, July 6, 2021.
    Copylight https://101010.fun
*/

#ifndef GasSensor_h // 2重インクルードを防ぐ
#define GasSensor_h

#include "M5StickCPlus.h"

class GasSensor {
    public:
        GasSensor(); // ←コンストラクタと合わせる
        void setup();
        void readSensor();
    private :
        bool _isSetuped;
  
}; // ←セミコロン忘れずに
#endif

/*
  GasSensor.cpp - Library for Gas sensor.
  Created by Toshihiko Arai, July 6, 2021.
  Copylight https://101010.fun
*/

#include "GasSensor.h"

#define PIN_HEATER 0
#define PIN_SENSOR 26
#define PIN_OUTPUT 36

uint16_t getColor(uint8_t red, uint8_t green, uint8_t blue){
    return ((red>>3)<<11) | ((green>>2)<<5) | (blue>>3);
}

const int SMELL_BAD = 1000;
const int SMELL_NORMAL = 4095;
const int SMELL_DIFF = SMELL_NORMAL - SMELL_BAD; // // 2500 - 2000

GasSensor::GasSensor() { // コンストラクタ
}

void GasSensor::setup() {
    if (!_isSetuped) {
        // M5.Lcd.setRotation(3);
        M5.Lcd.fillScreen(BLACK);
        M5.Lcd.setTextColor(WHITE);

        pinMode(PIN_HEATER,OUTPUT);
        pinMode(PIN_SENSOR,OUTPUT);
        digitalWrite(PIN_HEATER,LOW); // Heater Off
        digitalWrite(PIN_SENSOR,LOW); // Sensor Pullup Off

        pinMode(PIN_OUTPUT, INPUT);
        gpio_pulldown_dis(GPIO_NUM_25); // Disable pull-down on GPIO.
        gpio_pullup_dis(GPIO_NUM_25); // Disable pull-up on GPIO.
        _isSetuped = true;
        Serial.println("GasSensor 'setup' was completed!");        
    }
}

void GasSensor::readSensor() {
    int val = 0;
    int val_origin = 0;
    float rate = 0.0;
    
    delay(237);
    digitalWrite(PIN_SENSOR,HIGH); // Sensor Pullup On
    delay(3);
    val = analogRead(PIN_OUTPUT); // Get Sensor Voltage
    delay(2);
    digitalWrite(PIN_SENSOR,LOW); // Sensor Pullup Off
    
    digitalWrite(PIN_HEATER,HIGH); // Heater On
    delay(8);
    digitalWrite(PIN_HEATER,LOW); // Heater Off

//    Serial.println(val);
    val_origin = val;

    if (SMELL_BAD > val) {
        val = SMELL_BAD;
    } else if (SMELL_NORMAL < val) {
        val = SMELL_NORMAL;
    }
    val -= SMELL_BAD;
    rate = float(val) / float(SMELL_DIFF);
    Serial.println(rate);
    int red = int((1.0 - rate) * 255.0);
    int green = int(rate * 255.0);
//    Serial.println(red);
    M5.Lcd.fillScreen(getColor(red,green,0));
    M5.Lcd.setTextSize(2);
    M5.Lcd.setCursor(10, 10);
    M5.Lcd.printf("%d", val_origin);
    M5.Lcd.setTextSize(5);
    M5.Lcd.setCursor(35, 100);
    M5.Lcd.printf("%d", (int)(rate * 100.0));
}

#include <M5StickCPlus.h>
#include "GasSensor.h"

enum project_num {
    GAS_SENSOR = 1,
};

int selected_num = 0;

GasSensor gasSensor = GasSensor();

void setup() {
  // put your setup code here, to run once:
    M5.begin();
    M5.Axp.ScreenBreath(9);
    Serial.begin(115200);
}

void loop() {
    M5.update(); // Buttonの状態更新のため必要
    if(M5.BtnB.wasPressed()){
        selected_num++;
        if (selected_num > 1) {
            selected_num = 0;
        }  

        switch (selected_num) {
        case GAS_SENSOR:
            gasSensor.setup();
            break;
        }

    }

    switch (selected_num) {
        case GAS_SENSOR:
            gasSensor.readSensor();
            break;
    }

}