ESP8266でWiFi通信【ESP-WROOM-02・Arduino】

秋月電子で購入したESP8266 (ESP-WROOM-02)を使ってWiFi通信を行う方法を解説していく。 具体的には次の3つのステップで解説していく。

  1. ESP8266でLチカするまで
  2. ESP8266をウェブサーバーにする方法
  3. ESP8266からSSLでHTTPSリクエストする方法

なお、開発環境はMacで行った。

ESP8266でLチカするまで

ESP8266は秋月電子通商で購入したものを使った。

秋月電子通商で購入したESP8266
秋月電子通商で購入したESP8266

ここではESP-WROOM-02開発キットマニュアルを読みながら手順通り進めていく。 ESP-WROOM-02開発キットマニュアル - 秋月電子通商

動作確認

ESP8266のArduino IDE設定
ESP8266のArduino IDE設定

  1. USBでESP8266とMacをつなぐ(LEDが赤く点灯する)。
  2. Arduino IDEを立ち上げ、新規スケッチを開く。
  3. メニューのツール → シリアルポートの一覧からUSBポートを選択する。
  4. シリアルモニターを立ち上げ、改行を「CRおよびLF」にし、通信速度「115200bps」を選択する。
  5. ESP8266のRSTスイッチを押すと、文字化けしたメッセージが出てくるが、最後にReadyと帰って来ればOK。
  6. シリアルモニターから「AT」と入力して、OKと返ってくれば動作確認は完了。

適当にプログラムを作ってLチカまで試しておく。書き込みをするときは、RSTとPGMを同時に押して、RSTからPGMの順番に離す。ちなみにESP8266でLチカさせるのに70mA程度消費した。

ESP8266でLチカチカ
ESP8266でLチカチカ

ESP8266をウェブサーバーにする

次に、ESP8266をウェブサーバーにしてブラウザからWiFiでダイレクトアクセスできるようにしてみよう。まず、Arduino IDEのスケッチ例からESP8266WiFiWiFiAccessPointを開く。

WiFiAccessPointサンプルを開く
WiFiAccessPointサンプルを開く

サンプルプログラムのssidpasswordを自由に決め、ESP8266へアップロードする。ちなみにパスワードは8文字以上でないと上手くいかなかった。

cpp
#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>

/* Set these to your desired credentials. */
const char *ssid = "MyFi";
const char *password = "88888888"; // 8文字以上でないといけない?

ESP8266WebServer server(80);

/* Just a little test message.  Go to http://192.168.4.1 in a web browser
   connected to this access point to see it.
*/
void handleRoot() {
  server.send(200, "text/html", "&lt;h1&gt;Hello world!&lt;/h1&gt;");
}

void setup() {
  delay(1000);
  Serial.begin(115200);
  Serial.println();
  Serial.print("Configuring access point...");
  /* You can remove the password parameter if you want the AP to be open. */
  WiFi.softAP(ssid, password);

  IPAddress myIP = WiFi.softAPIP();
  Serial.print("AP IP address: ");
  Serial.println(myIP);
  server.on("/", handleRoot);
  server.begin();
  Serial.println("HTTP server started");
}

void loop() {
  server.handleClient();
}

シリアルモニタを開いてRSTボタンを押せば、ESP8266のIPアドレスが確認できる。ここではhttp://192.168.4.1/と表示された。

ESP8266のIPアドレスを確認
ESP8266のIPアドレスを確認

WEBブラウザからhttp://192.168.4.1/へアクセスすると「Hello world!」が表示される。

ブラウザに「Hello world!」の文字が表示された
ブラウザに「Hello world!」の文字が表示された

ESP8266からSSLでHTTPSリクエスト

最後に、ESP8266からSSLでHTTPSリクエストを行う。Arduino IDEのスケッチ例からESP8266WiFiHTTPSRequestを選択しよう。このプログラムを元に少しだけ編集する。HTTPSリクエスト先のサーバーは、Let's encryptを導入済みのレンタルサーバーを使った。

Arduinoスケッチ

cpp
#include <ESP8266WiFi.h>
#include <WiFiClientSecure.h>

const char* ssid = "Router SSID";
const char* password = "Router Password";

const char* host = "example.com";
const int httpsPort = 443;

void setup() {
  Serial.begin(115200);

  wifiInitialize();

}

void loop() {  
  String url = "/somedir/echo.php";
  String postData = "message=88888";
  httpsPost(url, postData);

  delay(3000);
}

void wifiInitialize() {
  Serial.println();
  Serial.print("connecting to ");
  Serial.println(ssid);
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void httpsPost(String url, String postData) {
  // Use WiFiClientSecure class to create TLS connection
  WiFiClientSecure client;
  Serial.print("connecting to ");
  Serial.println(host);
  if (!client.connect(host, httpsPort)) {
    Serial.println("connection failed");
    return;
  }

  Serial.print("requesting URL: ");
  Serial.println(url);

  client.println("POST " + url + " HTTP/1.1");
  client.println("Host: " + (String)host);
  client.println("User-Agent: ESP8266/001");
  client.println("Connection: close");
  client.println("Content-Type: application/x-www-form-urlencoded;");
  client.print("Content-Length: ");
  client.println(postData.length());
  client.println();
  client.println(postData);

  Serial.println("request sent");
  while (client.connected()) {
    String line = client.readStringUntil('\n');
    if (line == "\r") {
      Serial.println("headers received");
      break;
    }
  }
  String line = client.readStringUntil('\n');
  Serial.println("reply was:");
  Serial.println("==========");
  Serial.println(line);
  Serial.println("==========");
  Serial.println("closing connection");
}

サーバー側のスクリプト

サーバー側のスクリプトは次の通り。

php
$message = $_POST["message"];
$useragent = $_SERVER['HTTP_USER_AGENT'];

echo "Your message is \"". $message. ", UserAgent is \"". $useragent. "\"\n";

このように、ESP8266からHTTPSでリクエストできた。

Arduino IDEのシリアルモニター
Arduino IDEのシリアルモニター

関連記事

最後までご覧いただきありがとうございます!

▼ 記事に関するご質問やお仕事のご相談は以下よりお願いいたします。
お問い合わせフォーム

ESP32搭載ボード
ESP32の書籍
Arduinoで人気の周辺パーツ
M5Stackのオススメ参考書
M5Stack製品
M5StickCで使えるHat
ESP32ボード