Arduinoとサーミスタで温度測定

サーミスタ

ここではサーミスタについて解説します。

サーミスタとは

サーミスタとは、温度変化にともなって抵抗値が変化する抵抗器です。温度のthermalと抵抗器のresistorを合わせ、サーミスタという名称になりました。

温度センサに使用されるサーミスタは、NTC（negative temperature coefficient）といって、温度が上昇すると抵抗値が減少するタイプのものです。

温度が上昇すると抵抗値が上昇するものは、PTC（positive temperature coefficient）と呼び、ヒューズの役割として使ったり、一定温度を保つPTCヒーターに利用されます。

PTCヒータープレート DC 12V 80℃

Amazonで見る楽天市場で見る

ちなみにこちらのPTCヒーターを使ってヨーグルトメーカーをつくったことがあります。興味のある方はそうだ！Arduinoでヨーグルトメーカーをつくろう！をご覧ください。

本記事では、温度センサとしてよく使われるNTCタイプのサーミスタを扱います。

NTCサーミスタの特性・近似式

サーミスタは、温度変化に対して抵抗値が変わる素子であることは説明しました。しかしながら、サーミスタと温度と抵抗の関係は非線形です。よって、サーミスタの抵抗値から温度を得るためには、NTCサーミスタの特性を近似させた次式を利用します。

$$R=R_0exp\{B(\frac{1}{T}-\frac{1}{T_0})\} \tag{1}$$

ここで、BはB定数と呼ばれるもので、サーミスタのデータシートに掲載されています。

また、Tの単位はケルビンになります。摂氏温度を取得するには次式で変換します。

$$T(K)=t(℃)+273.15 \tag{2}$$

さて、式1をTについて展開すると次のとおりです。

$$\frac{1}{T} = \frac{1}{T_0}+\frac{1}{B}ln\frac{R}{R_0} \tag{3}$$

式3の逆数をとれば、Tについて算出できます。

さらに高精度で近似させる「スタインハート式」というものがありますが、式3でも実用的な温度測定ができますので「スタインハート式」については省略します。

＼スタインハート式を使った校正／

スタインハート式を使ったサーミスタの温度校正のやり方｜Arduino・ESP32

2023-01-06 Arduino

Arduinoでサーミスタを使う

実際にArduinoでサーミスタを使っていきましょう。

Arduinoとサーミスタの配線

こちらの図のように、Arduinoとサーミスタを配線します。

Arduinoとサーミスタの配線

サーミスタと固定抵抗で分圧した値を、Arduinoのアナログ入力で読み取り、サーミスタの抵抗値を算出します。

サーミスタ103JT-050では、25℃のときに10kΩの抵抗値になりますので、固定抵抗を10kΩとしました。ここらへんは、測定したい温度範囲によって変えてもらって構いません。また、固定抵抗にはできるだけ誤差の少ない金属皮膜抵抗を使用しましょう。

センサにかける電圧は5Vを使用しました。

サーミスタで温度測定するソースコード

こちらが、Arduinoとサーミスタを使って温度を測定するソースコードになります。

#include <math.h>

#define THERMISTOR_PIN 0

const float DIVIDER = 10000.0; // 分圧抵抗10kΩ

const float T0 = 273.15;
const float R0 = 27700.0;
const float B = 3435.0;

float calcTemp(float Rt) {
  float T_bar = 1/T0 + 1/B * log(Rt/R0);
  return 1.0/T_bar - 273.15;
}


void setup() {
  Serial.begin(9600);
  pinMode(THERMISTOR_PIN, INPUT);

}


void loop() {
  float Aout =  float(analogRead(THERMISTOR_PIN));
//  Serial.println(Aout);
  float Rt = DIVIDER * Aout / (1024.0 - Aout);
  
  float temp = calcTemp(Rt);
  Serial.println(temp);
  delay(1000);
}

ソースコードの解説

サーミスタの抵抗値Rtの算出

loop関数内では、アナログ入力値からサーミスタの抵抗値を算出しています。

サーミスタ温度センサの回路図

抵抗値とADCの値の比を考えると、次式のようになります。

$$Aout:1024-Aout = R_t:10k \tag{4}$$

式4より、Rtについて解くと次式となります。

$$R_t=\frac{10k \times Aout}{1024-Aout} \tag{5}$$

居酒屋ガレージ日記さん にご指摘いただきまして、1023で割っていた式を1024に修正させていただきます。そもそもADコンバータで測れる値は、

$$V_{ref} - 1LSB  = V_{ref} (1 - 1/1024)$$

という事らしいです。ですから厳密には、図中の5Vを\(V_{ref} - 1LSB\)にするのが正解なような気がします。

近似値の計算

calcTemp関数では、式3の近似値の計算式をそのままプログラミングしています。

サーミスタと分圧抵抗をステレオミニにまとめてはんだ付けしました。VccをTip、AoutをRing、GNDをSleeveに割り当てています。

サーミスタのステレオミニ化

ステレオミニですと、簡単にセンサのケーブルを延長できるので便利です。